Merge pull request #22 from utox39/feat/window-manager

fix(macos-wm): fix wrong array size

README.md

@@ -94,6 +94,7 @@ Available modules:
 -   Swap
 -   Disk
 -   Net
+-   WM (Window Manager)
 -   Terminal
 -   Locale
 -   Custom
@@ -111,6 +112,7 @@ Available modules:
 |    swap     |       Yes       |           Yes            |   WIP   |
 |    disk     |       Yes       |           Yes            |   WIP   |
 |     net     |       Yes       |           Yes            |   WIP   |
+|     wm      |       Yes       |           Yes            |   WIP   |
 |  terminal   |       Yes       |           Yes            |   WIP   |
 |   locale    |       Yes       |           Yes            |   WIP   |
 

build.zig.zon

@@ -10,7 +10,7 @@
 
     // This is a [Semantic Version](https://semver.org/).
     // In a future version of Zig it will be used for package deduplication.
-    .version = "0.22.1",
+    .version = "0.23.0",
 
     // Together with name, this represents a globally unique package
     // identifier. This field is generated by the Zig toolchain when the

src/config.zig

@@ -25,6 +25,7 @@ pub const ModuleType = enum {
     swap,
     disk,
     net,
+    wm,
     terminal,
     locale,
     custom,

src/formatters.zig

@@ -20,6 +20,7 @@ pub const formatters = [_]*const fn (allocator: std.mem.Allocator, key: []const
     &getFormattedSwapInfo,
     &getFormattedDiskInfo,
     &getFormattedNetInfo,
+    &getFormattedWindowManagerInfo,
     &getFormattedTerminalNameInfo,
     &getFormattedLocaleInfo,
     &getFormattedCustom,
@@ -37,6 +38,7 @@ pub const default_formatters = [_]*const fn (allocator: std.mem.Allocator) anyer
     &getDefaultFormattedSwapInfo,
     &getDefaultFormattedDiskInfo,
     &getDefaultFormattedNetInfo,
+    &getDefaultFormattedWindowManagerInfo,
     &getDefaultFormattedTerminalNameInfo,
     &getDefaultFormattedLocaleInfo,
 };
@@ -192,6 +194,16 @@ pub fn getFormattedDiskInfo(allocator: std.mem.Allocator, key: []const u8, key_c
     return Result{ .string = try std.fmt.allocPrint(allocator, "{s}{s} ({s}):{s} {d:.2} / {d:.2} GB ({}%)", .{ key_color, key, disk_info.disk_path, ascii.Reset, disk_info.disk_usage, disk_info.disk_size, disk_info.disk_usage_percentage }) };
 }
 
+pub fn getDefaultFormattedWindowManagerInfo(allocator: std.mem.Allocator) !Result {
+    return try getFormattedWindowManagerInfo(allocator, "WM", ascii.Yellow);
+}
+
+pub fn getFormattedWindowManagerInfo(allocator: std.mem.Allocator, key: []const u8, key_color: []const u8) !Result {
+    const wm = try detection.system.getWindowManagerInfo(allocator);
+    defer allocator.free(wm);
+    return Result{ .string = try std.fmt.allocPrint(allocator, "{s}{s}:{s} {s}", .{ key_color, key, ascii.Reset, wm }) };
+}
+
 pub fn getDefaultFormattedTerminalNameInfo(allocator: std.mem.Allocator) !Result {
     return try getFormattedTerminalNameInfo(allocator, "Terminal", ascii.Yellow);
 }

src/linux/system.zig

@@ -98,3 +98,58 @@ pub fn getOsInfo(allocator: std.mem.Allocator) ![]u8 {
 
     return try allocator.dupe(u8, pretty_name orelse "Unknown");
 }
+
+pub fn getWindowManagerInfo(allocator: std.mem.Allocator) ![]const u8 {
+    var dir = try std.fs.cwd().openDir("/proc/", .{ .iterate = true });
+    defer dir.close();
+
+    var wm_name: ?[]const u8 = null;
+
+    var iter = dir.iterate();
+    wm_name = outer: {
+        while (try iter.next()) |entry| {
+            if (entry.kind != .directory) continue;
+
+            // Check if the entry name is numeric
+            _ = std.fmt.parseInt(i32, entry.name, 10) catch continue;
+
+            var buf: [1024]u8 = undefined;
+            const file_name = try std.fmt.bufPrint(&buf, "/proc/{s}/comm", .{entry.name});
+            const file = try std.fs.cwd().openFile(file_name, .{ .mode = .read_only });
+            defer file.close();
+
+            // NOTE: https://stackoverflow.com/questions/23534263/what-is-the-maximum-allowed-limit-on-the-length-of-a-process-name
+            var file_buf: [16]u8 = undefined;
+            var reader = std.fs.File.Reader.init(file, &file_buf);
+            const read = try reader.read(&file_buf);
+            const proc_name = file_buf[0..read];
+
+            const proc_name_trimmed = std.mem.trim(u8, proc_name, "\n");
+
+            const supported_wms: [9][]const u8 = .{
+                "i3", // https://i3wm.org/
+                // "i3gaps", // TODO: find a way to recognize i3gaps
+                "sway", // https://swaywm.org/
+                // "swayfx", // TODO: find a way to recognize swayfx
+                "niri", // https://github.com/YaLTeR/niri
+                "dwm", // https://dwm.suckless.org/
+                // "qtile", // TODO: find a way to recognize qtile
+                "awesome", // https://awesomewm.org/
+                "river", // https://codeberg.org/river/river
+                "hyprland", // https://hypr.land/
+                "bspwm", // https://github.com/baskerville/bspwm
+                "openbox", // https://openbox.org/
+            };
+
+            inline for (supported_wms) |wm| {
+                if (std.ascii.eqlIgnoreCase(wm, proc_name_trimmed)) {
+                    break :outer try allocator.dupe(u8, proc_name_trimmed);
+                }
+            }
+        }
+
+        break :outer null;
+    };
+
+    return wm_name orelse allocator.dupe(u8, "Unknown");
+}

src/macos/system.zig

@@ -128,3 +128,68 @@ pub fn getOsInfo(allocator: std.mem.Allocator) ![]u8 {
 
     return os_info;
 }
+
+pub fn getWindowManagerInfo(allocator: std.mem.Allocator) ![]const u8 {
+    var name = [_]c_int{ c_sysctl.CTL_KERN, c_sysctl.KERN_PROC, c_sysctl.KERN_PROC_ALL };
+    var size: usize = 0;
+
+    // First call to get the dimension
+    if (c_sysctl.sysctl(&name, name.len, null, &size, null, 0) != 0) {
+        return error.SysctlFailed;
+    }
+
+    const buffer: []u8 = try allocator.alloc(u8, size);
+    defer allocator.free(buffer);
+
+    // Second call to retrieve process data
+    if (c_sysctl.sysctl(&name, name.len, buffer.ptr, &size, null, 0) != 0) {
+        return error.SysctlFailed;
+    }
+
+    // Ensure the buffer size is valid
+    if (size % @sizeOf(c_sysctl.struct_kinfo_proc) != 0) {
+        return error.InvalidBufferSize;
+    }
+
+    const kinfo_list = std.mem.bytesAsSlice(c_sysctl.struct_kinfo_proc, buffer);
+
+    var wm_name: ?[]const u8 = null;
+
+    const supported_wms: [6][]const u8 = .{
+        "aerospace",
+        "amethyst",
+        "chunkwm",
+        "rectangle",
+        "spectacle",
+        "yabai",
+    };
+
+    wm_name = outer: {
+        for (kinfo_list) |kinfo| {
+            const pid = kinfo.kp_proc.p_pid;
+            if (pid <= 0) continue;
+
+            // Gets the process pathname
+            var pathbuf: [c_libproc.PROC_PIDPATHINFO_MAXSIZE]u8 = undefined;
+            // c_libproc.proc_pidpath saves the process name in `pathbuf` and returns the len
+            const path_len = @as(usize, @intCast(c_libproc.proc_pidpath(pid, &pathbuf, pathbuf.len)));
+            const proc_pathname = if (path_len > 0) try allocator.dupe(u8, pathbuf[0..@intCast(path_len)]) else try allocator.dupe(u8, "unknown");
+            defer allocator.free(proc_pathname);
+
+            inline for (supported_wms) |wm| {
+                if (std.ascii.endsWithIgnoreCase(proc_pathname, wm)) {
+                    const basename = if (std.mem.lastIndexOfScalar(u8, proc_pathname, '/')) |index|
+                        proc_pathname[index + 1 ..]
+                    else
+                        proc_pathname;
+
+                    break :outer try allocator.dupe(u8, basename);
+                }
+            }
+        }
+
+        break :outer null;
+    };
+
+    return wm_name orelse allocator.dupe(u8, "Quartz Compositor");
+}